@ECHO OFF &SETLOCAL ENABLEEXTENSIONS
:DELAYIT
IF [%1] NEQ [] (ECHO %1%2|FINDSTR/R "[^0-9]">NUL||GOTO SHOWIT)
ECHO/ INVALID PARAMETERS &&%0 0 5
:SHOWIT
IF [%2] EQU [] SET /A "ALLSECS=60*%1"
IF NOT DEFINED ALLSECS SET /A "ALLSECS=60*%1+%2"
SET /A "MINUTES=ALLSECS/60"
SET /A "SECONDS=ALLSECS-(MINUTES*60)"
IF %MINUTES% EQU 1 (SET MINS=minute) ELSE (SET MINS=minutes)
IF %SECONDS% EQU 1 (SET SECS=second) ELSE (SET SECS=seconds)
IF %MINUTES% EQU 0 (IF %SECONDS% EQU 0 (
  ECHO/ NO DELAY GIVEN &&(ENDLOCAL &&%0 0 5 &GOTO :EOF))
  IF DEFINED SECONDS ECHO/ Pausing for %SECONDS% %SECS%...) ELSE (
  IF %SECONDS% EQU 0 (ECHO/ Pausing for %MINUTES% %MINS%...) ELSE (
  ECHO/ Pausing for %MINUTES% %MINS% and %SECONDS% %SECS%...))
SET /A "DELAY=100*ALLSECS" &SET "TIME_=%TIME%"
SET "TIME_=%TIME_::0=:%"
SET "TIME_=%TIME_:.0=.%"
SET "TIME_=%TIME_: =%"
FOR /F "TOKENS=1-4 DELIMS=:. " %%a IN ('ECHO/%TIME_%') DO (
  SET /A "START_=360000*%%a+6000*%%b+100*%%c+%%d")
:LOOPIT
SET "TIME_=%TIME%"
SET "TIME_=%TIME_::0=:%"
SET "TIME_=%TIME_:.0=.%"
SET "TIME_=%TIME_: =%"
FOR /F "TOKENS=1-4 DELIMS=:. " %%a IN ('ECHO/%TIME_%') DO (
  SET /A "NOW_=360000*%%a+6000*%%b+100*%%c+%%d")
SET /A "DIFF=NOW_-START_+1"
IF %DIFF% LSS %DELAY% GOTO LOOPIT
ECHO/ Continuing... &&ENDLOCAL&GOTO :EOF